03-日期处理

获取日期信息 ^{YEAR()、MONTH()、DAY()、NOW()、TODAY()…}
日期数据转为文本信息 ^{TEXT()、DATESTRING()}
文本转为时间日期格式 ^{DATEVALUE()、TIMEVALUE()}
日期数据计算 ^{DATEDIF()、DAYS()、EDATE()}

获取日期信息

A1范例	功能	公式	效果
`2020/1/1 10:20:30`	返回年份	`=YEAR(A1)`	2020
	返回月份	`=MONTH(A1)`	1
	返回天数	`=DAY(A1)`	1
	返回星期几（2：周一从1开始）	`=WEEKDAY(A1,2)`	3
	返回小时	`=HOUR(A1)`	10
	返回分钟	`=MINUTE(A1)`	20
	返回秒	`=SECOND(A1)`	30

其他常用日期函数：
- 获取系统当前时间：=NOW()
- 获取系统当天日期：=TODAY()
- 根据年月日拼接日期信息：=DATE("年","月","日")
- 根据时分秒拼接时间数据：=TIME("时","分","秒")

日期数据转为文本信息

A1范例	功能	公式	效果
`2020/1/1`	年/月/日	`=TEXT(A1,"yyyy/mm/dd")`	2020/01/01
	年/月/日星期	`=TEXT(A1,"yyyy/mm/dd aaaa")`	2020/01/01 星期三
	年-月-日	`=TEXT(A1,"yyyy-mm-dd")`	2020-01-01
	年月日	`=TEXT(A1,"emmdd")`	20200101
	年月日	`=DATESTRING(A1)`	20年01月01日
	年月	`=TEXT(A1,"yyyy年m月")`	2020年1月
	年	`=TEXT(A1,"yyyy")`	2020
	年(末两位缩写)	`=TEXT(A1,"yy")`	20
	季度	`="Q"&LEN(2^MONTH(A1))`	Q1
	月	`=TEXT(A1,"mm")`	01
	月(英文缩写)	`=TEXT(A1,"mmm")`	Jan
	月(英文)	`=TEXT(A1,"mmmm")`	January
	月份的上中下旬	`=LOOKUP(DAY(A1),{0,11,21},{"上旬","中旬","下旬"})`	上旬
	星期(中文缩写)	`=TEXT(A1,"aaa")`	三
	星期(中文)	`=TEXT(A1,"aaaa")`	星期三
	星期(英文缩写)	`=TEXT(A1,"ddd")`	Wed
	星期(英文)	`=TEXT(A1,"dddd")`	Wednesday

文本转为时间日期格式

注意：仅对文本格式的时间才有效。

A1范例	功能	公式	效果
`2020年1月1日`	字符串转日期格式	`=DATEVALUE(A1)`	2020/1/1
`20200101`	字符串转日期格式	`=DATEVALUE(TEXT(A1,"#-00-00"))`	2020/1/1
`10时20分`	字符串转时间格式	`=TIMEVALUE(SUBSTITUTE(SUBSTITUTE(A1,"分",""),"时",":"))`	10:20:00
`1602122881000`	时间戳转时间格式	`=TEXT((A1/1000+83600)/86400+70365+19,"yyyy-mm-dd hh:mm:ss")`	2020-10-08 10:08:01

日期数据计算

A1范例	B1范例	功能	公式	效果
`2020/1/1`	`2021/1/31`	统计相差的天数-方法1	`=B1-A1`	396
		统计相差的天数-方法2	`=DAYS(B1,A1)`	396
		统计相差的天数-方法3	`=DATEDIF(A1,B1,"D")`	396
		统计相差的月份	`=DATEDIF(A1,B1,"M")`	12
		统计相差的年份	`=DATEDIF(A1,B1,"Y")`	1
		忽略年，统计相差的天数	`=DATEDIF(A1,B1,"YD")`	30
		忽略年、月，统计相差的天数	`=DATEDIF(A1,B1,"MD")`	30
		忽略年、日，统计相差的月份	`=DATEDIF(A1,B1,"YM")`	0

A1范例	功能	公式	效果
`2020/1/1`	计算日期1个月份后的日期	`=EDATE(A1,1)`	2020/2/1

04-重复值处理>

返回顶部 ↑